Porovnanie dvoch stĺpcov | Porovnanie viacerých stĺpcov | Porovnanie dvoch tabuliek
Ukážeme si, ako môžeme bleskurýchle porovnať dve tabuľky v Exceli. Ako vytvoriť, spracovať a využiť tabuľky v náš prospech preberám v našom kompletnom video kurze Excelu.
Ak chceme porovnať dva stĺpce, môžeme tak urobiť viacerými spôsobmi.
Ak máme dva stĺpce a chceme zistiť riadok po riadku, či majú bunky rovnakú hodnotu, použijeme funkciu IF a logický operátor =
Napríklad do bunky pre porovnanie vpíšeme
=IF(A1=B1,”Zhoda”,”Nezhoda”)
Pričom:
· Prvý argument – podmienka – : A1=B1
· Druhý argument – čo cheme, aby Excel vrátil, ak je podmienka splnená – : “Zhoda”
· Tretí argument – čo chceme, aby Excel vrátil, ak podmienka nie je splnená – : “Nezhoda”
Ak chceme zistiť, či sa líšia, použijeme funkciu IF a logický operátor <>
=IF(A1<>B1,”Nezhoda”,”Zhoda”)
Samozrejme pri takto jednoduchej forme využitia funkie IF nezáleží na tom, či použijeme logický operátor = alebo <>, výsledok bude rovnaký.
Ak ste si všimli na príklade, v riadku 4 nám vrátilo Zhoda napriek tomu, že v jednej bunke máme text s veľkými písmenami a v druhom s malými.
Funkciu IF bližšie preberám v článku Funkcia IF.
Ak chceme, aby Excel rozlišoval veľké a malé písmená, použijeme funkciu EXACT
=IF(EXACT(A4,B4),”Zhoda”,”Nezhoda”)
Ak chceme zistiť pre každú hodnotu v stĺpci A (pre každý riadok), či takúto hodnotu máme aj niekde v stĺpci B, použijeme funkciu MATCH a zaobalíme ju do funkcie IFERROR.
=IFERROR(MATCH(A1,B:B,0),"")
Do tretieho argumentu sme pridali 0. To znamená, že hľadáme presnú zhodu.
Táto funkcia nám vráti riadok stĺpca B, v ktorom sa nachádza hľadaná hodnota zo stĺpca A.
Ak chceme zistiť, či je rovnaká hodnota vo všetkých stĺpcoch, záleží na tom koľko stĺpcov chceme porovnať.
Ak chceme porovnať len pár stĺpcov, môžme použiť kombináciu funkcií IF a AND.
=IF(AND(A1=B1,A1=C1),”Zhoda”,”Nezhoda”)
Ak chceme porovnať veľa stĺpcov, radšej použijeme kombináciu funkcií IF a COUNTIF a COUNTA.
=IF(COUNTIF(A1:F1,A1)=COUNTA(A1:F1),"Zhoda","Nezhoda")
Ak chceme zistiť, či máme aspoň jednu zhodu medzi akýmikoľvek dvomi stĺpcami v našich stĺpcoch, môžeme využiť funkciu IF a kombináciu funkcií COUNTIF a COUNTA.
=IF(COUNTIF(A2:C2,A2)+COUNTIF(A2:C2,B2)+COUNTIF(A2:C2,C2)>COUNTA(A2:C2),"Existuje zhoda","Ani jedna zhoda")
V prípade, že ani jedna dvojica buniek sa nezhoduje, nám každý COUNTIF vráti hodnotu presne 1. Dokopy teda to bude číslo, ktoré sa rovná počtu stĺpcov ktoré porovnávame, teda COUNTA. Funkcia IF nám vráti "Ani jedna zhoda".
V prípade, že aspoň jedna dvojica buniek sa zhoduje, COUNTIF pre tieto bunky nám vráti hodnotu väčšiu ako 1, a teda súčet našich hodnôt COUNTIF bude väčší ako počet stĺpcov (ktorý získavame pomocou COUNTA). Funkcia IF nám vráti "Existuje zhoda".
Ak máme dve tabuľky a chceme porovnať, či sú hodnoty v ich bunkách rovnaké, môžeme použiť funkciu IF podobne ako pri dvoch stĺpcoch.
=IF(B4=E4,“Zhoda”,”Nezhoda”)
Vidíme, že zhodu máme iba medzi bunkami B5 a E5.
Toto zistenie nám však toho veľa nepovie.
Ak by sme chceli zistiť, či v tabuľke 2 máme všetky produkty, ktoré máme v tabuľke 1, použili by sme funkciu COUNTIF.
Do bunky H4 vpíšeme:
=COUNTIF($E$4:$E$12,B4)
Skopírujeme pre ostatné bunky.
Táto funkcia nám vrátila 1 pre všetky bunky, čiže máme každý produkt z tabuľky 1 aj v tabuľke 2 presne jeden krát. Ak by nám COUNTIF niekde vrátilo 0, znamenalo by to, že v tabuľke 2 nemáme daný produkt z tabuľky 1. Ak by nám naopak COUNTIF vrátil hodnotu vačšiu ako 1, znamenalo by to, že máme daný produkt z tabuľky 1 v tabuľke 2 viac krát.
Viac o funkcií COUNTIF v článku Funkcia Excel COUNTIF.
Ak by sme chceli vedieť aj presný riadok tabuľky, v ktorom sa nachádza údaj z inej, môžeme použiť funkciu MATCH.
=MATCH(B4,$E$4:$E$12,0)
Napríklad v bunke H4 nám vrátila funkcia MATCH hodnotu 3, pretože produkt A (z bunky B4) je v treťom riadku tabuľky 2.
Ak by sme chceli vypísať ceny produktov z dvoch tabuliek to jednej, môžeme na to využiť funkciu VLOOKUP.
V stĺpci H a I si skopírujeme produkty a ceny z tabuľky 1. V stĺpci J použijeme pre vyhľadanie ceny daného produktu z tabuľky 2 funkciu nasledovne:
=VLOOKUP(H4,$E$4:$F$12,2,FALSE)
Pričom:
· Argument 1 – hodnota, ktorú hľadáme. Hľadáme meno produktu z riadku, v ktorom hľadáme a stĺpca H –: H4
· Argument 2 – tabuľka, v ktorej hľadáme (zafixujeme si ju pomocou $) –: $E$4:$F$12
· Argument 3 – stĺpec z tabúľky, z ktore chceme vrátiť hodnoty (chceme hodnoty z druhého stĺpca v tabuľke $E$4:$F$12) –: 2
· Argument 4 – hľadáme presnú zhodu, preto zvolíme –: FALSE
Funkciu VLOOKUP podrobne preberám v článku Funkcia VLOOKUP. Viac info o iných funkciách nájdete v sekcií Funkcie a vzorce.
Náš video kurz Excelu